1. Toy模板网首页
  2. > Toy博客

FPGA：uart原理+tx发送模块+rx接收模块

9月前 作者：Fu-yu 分类：Toy博客 阅读(36) 违法举报

这篇具有很好参考价值的文章主要介绍了FPGA：uart原理+tx发送模块+rx接收模块。希望对大家有所帮助。如果存在错误或未考虑完全的地方，请大家不吝赐教，您也可以点击"举报违法"按钮提交疑问。

一、串口通信

处理器与外部设备通信的两种方式：
串行通信： 指数据的各个位使用多条数据线同时进行传输。
并行通信： 将数据分成一位一位的形式在一条数据线上逐个传输。
FPGA：uart原理+tx发送模块+rx接收模块,fpga开发

串行通信的通信方式：
同步通信： 带时钟同步信号的数据传输，发送方和接收方在同一时钟控制下，同步传输数据。
异步通信： 不带时钟同步信号的数据传输，发送方和接收方使用各自的时钟控制数据的发送和接收过程。FPGA：uart原理+tx发送模块+rx接收模块,fpga开发

串行通信的传输方向：
单工： 数据只能沿一个方向进行传输。
半双工： 数据传输可以沿两个方向，但需要分时进行。
全双工： 数据可以同时进行双向传输。
FPGA：uart原理+tx发送模块+rx接收模块,fpga开发

常见的串行通信接口：
FPGA：uart原理+tx发送模块+rx接收模块,fpga开发

二、UART通信

通用异步收发传输器(Universal Asynchronous Receiver/Transmitter)，通常称作UART，是一种异步收发传输器。 它在发送数据时将并行数据转换为串行的数据来传输，在接收数据时将接收到的串行数据转换成并行数据。UART串口通信需要两根信号线来实现，一根用于发送，另一个用于接收。
FPGA：uart原理+tx发送模块+rx接收模块,fpga开发

协议层：
数据格式，1帧数据由4部分组成。

  • 起始位（1bit）
  • 数据位（6/7/8bit）
  • 奇偶校验位（1bit）
  • 停止位（1bit/1.5bit/2bit）
    FPGA：uart原理+tx发送模块+rx接收模块,fpga开发

奇校验：原始码流+校验位 总共有奇数个1
偶校验：原始码流+校验位 总共有偶数个1

传输速率：
串口通信速率用波特率表示，它表示每秒传输二进制数据的位数，单位是bit/s（位/秒），简称bps；常用的波特率有9600，115200等。

物理层：
串口电平标准：

  • TTL电平的串口（3.3V）
  • RS232电平的串口（+5V ~ +12V为低电平，-12V ~ -5V为高电平)

三、tx发送模块

tx发送模块：共四个状态，IDLE状态，START状态，DATA状态，FINISH状态。

/*
 * @Description: tx输出,波特率115200，系统时钟50M，传输1bit所需计数434个周期
 * @Author: Fu Yu
 * @Date: 2023-08-15 11:10:41
 * @LastEditTime: 2023-08-15 14:55:04
 * @LastEditors: Fu Yu
 */

module uart_tx (
    input           wire                clk         ,
    input           wire                rst_n       ,
    input           wire [7:0]          tx_din      ,
    input           wire                tx_din_vld  ,

    output          wire                tx_dout     ,
    output          wire                ready           
);

parameter MAX_BIT = 50_000_000/115200;//1bit计数最大值,434

localparam  IDLE   = 4'b0001,
            START  = 4'b0010,
            DATA   = 4'b0100,
            FINISH = 4'b1000;

reg [3:0]   state_c;//现态
reg [3:0]   state_n;//次态

wire        idle_start  ;// IDLE -> START
wire        start_data  ;// START -> DATA
wire        data_finish ;// DATA -> FINISH
wire        finish_idle ;// FINFISH -> IDLE

reg			[8:0]	cnt_bit	   	;
wire				add_cnt_bit	;
wire				end_cnt_bit	;

reg			[11:0]	cnt_data	   	;
wire				add_cnt_data	;
wire				end_cnt_data	;

reg [7:0]   tx_din_r;
reg         tx_dout_r;

//****************************************************************
//--                状态机
//****************************************************************
always @(posedge clk or negedge rst_n) begin
    if(!rst_n) begin
        state_c <= IDLE;
    end
    else begin
        state_c <= state_n;
    end
end

always @( *) begin
    case (state_c)
        IDLE : begin
            if(idle_start) begin
                state_n = START;
            end
            else begin
                state_n = state_c;
            end
        end

        START : begin
            if(start_data) begin
                state_n = DATA;
            end
            else begin
                state_n = state_c;
            end
        end

        DATA : begin
            if(data_finish) begin
                state_n = FINISH;
            end
            else begin
                state_n = state_c;
            end
        end

        FINISH : begin
            if(finish_idle) begin
                state_n = IDLE;
            end
            else begin
                state_n = state_c;
            end
        end

        default : state_n = IDLE;
            
    endcase
end


assign idle_start  = state_c == IDLE && tx_din_vld ;
assign start_data  = state_c == START &&  end_cnt_bit;
assign data_finish = state_c == DATA &&  end_cnt_data;
assign finish_idle = state_c == FINISH && end_cnt_bit;

//****************************************************************
//--                    计数器
//****************************************************************
//1bit计数器
always @(posedge clk or negedge rst_n)begin 
   if(!rst_n)begin
        cnt_bit <= 'd0;
    end 
    else if(add_cnt_bit)begin 
        if(end_cnt_bit)begin 
            cnt_bit <= 'd0;
        end
        else begin 
            cnt_bit <= cnt_bit + 1'b1;
        end 
    end
end 

assign add_cnt_bit = state_c == START || state_c == FINISH || state_c == DATA;
assign end_cnt_bit = add_cnt_bit && cnt_bit == MAX_BIT - 1;

//8bit计数器
always @(posedge clk or negedge rst_n)begin 
   if(!rst_n)begin
        cnt_data <= 'd0;
    end 
    else if(add_cnt_data)begin 
        if(end_cnt_data)begin 
            cnt_data <= 'd0;
        end
        else begin 
            cnt_data <= cnt_data + 1'b1;
        end 
    end
end 

assign add_cnt_data = state_c == DATA && end_cnt_bit;
assign end_cnt_data = add_cnt_data && cnt_data == 8 - 1 ;


//****************************************************************
//--                输入数据寄存
//****************************************************************
always @(posedge clk or negedge rst_n) begin
    if(!rst_n) begin
        tx_din_r <= 0;
    end
    else begin
        tx_din_r <= tx_din;
    end
end


//****************************************************************
//--            实现串口时序
//****************************************************************
always @( *) begin
    case (state_c)
        IDLE : begin
            tx_dout_r = 1;
        end

        START : begin
            tx_dout_r = 0;
        end

        DATA : begin
            if(tx_din_r[cnt_data]) begin
                tx_dout_r = 1;
            end
            else begin
                tx_dout_r = 0;
            end
        end

        FINISH : begin
            tx_dout_r = 1;
        end

        default : tx_dout_r = 1;
    endcase
end

assign tx_dout = tx_dout_r;

assign ready = state_c == IDLE;


endmodule //uart_tx

测试文件：

/*
 * @Description: uart_tx仿真模块
 * @Author: Fu Yu
 * @Date: 2023-08-15 14:58:32
 * @LastEditTime: 2023-08-15 15:06:49
 * @LastEditors: Fu Yu
 */


`timescale 1ns/1ns
    
module tb_uart_tx();

//激励信号定义 
    reg				tb_clk  	;
    reg				tb_rst_n	;
    reg		[7:0]   tb_tx_din	;
    reg             tb_tx_din_vld;

//输出信号定义	 
    wire			tx_dout	;
    wire			ready    ;

//时钟周期参数定义	
    parameter		CLOCK_CYCLE = 20;   
    defparam  u_uart_tx.MAX_BIT = 10;
//模块例化
uart_tx u_uart_tx(
   /*input           wire       */  .       clk       (tb_clk)  ,
   /*input           wire       */  .       rst_n     (tb_rst_n)  ,
   /*input           wire [7:0] */  .       tx_din    (tb_tx_din) ,
   /*input           wire       */  .       tx_din_vld(tb_tx_din_vld) ,
   /*output          wire       */  .       tx_dout   (tx_dout)  ,
   /*output          wire       */  .       ready     (ready)      
);

//产生时钟
    initial 		tb_clk = 1'b0;
    always #(CLOCK_CYCLE/2) tb_clk = ~tb_clk;

//产生激励
    initial  begin 
        tb_rst_n = 1'b1;
        tb_tx_din = 0;
        tb_tx_din_vld = 0;
        #(CLOCK_CYCLE*2);
        tb_rst_n = 1'b0;
        #(CLOCK_CYCLE*20);
        tb_rst_n = 1'b1;

        
        repeat(10) begin
            tb_tx_din_vld = 1;
            tb_tx_din = {$random};
            #20;
            tb_tx_din_vld = 0;
            wait(ready == 1);
            #20;
        end

        #1000;
        $stop;
    end

endmodule

仿真波形图：
FPGA：uart原理+tx发送模块+rx接收模块,fpga开发
上板验证：
加入按键控制模块，每一次按下，输出8’hAB

按键消抖模块：

/*
 * @Description: 按键消抖，使用延迟方法，消抖后输出高电平信号
 * @Author: Fu Yu
 * @Date: 2023-08-07 14:22:56
 * @LastEditTime: 2023-08-07 14:48:48
 * @LastEditors: Fu Yu
 */


module key_filter #(
    parameter WITDH = 3//WITDH表示位宽
)(
    input       wire                clk         ,
    input       wire                rst_n       ,

    input       wire [WITDH-1:0]    key_in      ,

    output      wire [WITDH-1:0]    key_down
);

parameter MAX_20MA = 20'd999_999;//20ms

reg [WITDH - 1:0]   key_r0;//同步信号
reg [WITDH - 1:0]   key_r1;//打拍
reg [WITDH - 1:0]   key_r2;
reg [WITDH - 1:0]   key_down_r;
reg [19:0]          cnt_20ms;
reg                 flag;//开始计数信号

wire [WITDH - 1:0]  nedge;//下降沿
wire add_cnt_20ms;
wire end_cnt_20ms;


//****************************************************************
//--同步，打拍
//****************************************************************
always @(posedge clk or negedge rst_n) begin
    if(!rst_n) begin
        key_r0 <= {WITDH{1'b1}};
        key_r1 <= {WITDH{1'b1}};
        key_r2 <= {WITDH{1'b1}};
    end
    else begin
        key_r0 <= key_in;
        key_r1 <= key_r0;
        key_r2 <= key_r1;
    end
end

//下降沿检测
assign nedge = ~key_r1 & key_r2;


//****************************************************************
//--flag
//****************************************************************
always @(posedge clk or negedge rst_n) begin
    if(!rst_n) begin
        flag <= 1'b0;
    end
    else if(nedge) begin//检测到下降沿开始计数
        flag <= 1'b1;
    end
    else if(end_cnt_20ms) begin//20ms后停止计数
        flag <= 1'b0;
    end
    else begin
        flag <= flag;
    end
end


//****************************************************************
//--20ms计数器
//****************************************************************


always @(posedge clk or negedge rst_n)begin 
   if(!rst_n)begin
        cnt_20ms <= 20'd0;
    end 
    else if(add_cnt_20ms)begin 
        if(end_cnt_20ms)begin 
            cnt_20ms <= 20'd0;
        end
        else begin 
            cnt_20ms <= cnt_20ms + 1'b1;
        end 
    end
end 

assign add_cnt_20ms = flag;
assign end_cnt_20ms = add_cnt_20ms && cnt_20ms == MAX_20MA;

//****************************************************************
//--key_down
//****************************************************************
always @(posedge clk or negedge rst_n) begin
    if(!rst_n) begin
        key_down_r <= {WITDH{1'b0}};
    end
    else if(end_cnt_20ms) begin
        key_down_r <= ~key_r2;
    end
    else begin
        key_down_r <= {WITDH{1'b0}};
    end
end

assign key_down = key_down_r;

endmodule //key_filter

顶层模块：

module top (
    input           wire            clk         ,
    input           wire            rst_n       ,
    input           wire            key_in      ,

    output          wire            tx
);


wire        key_wire;
wire        ready;


key_filter #(.WITDH(1)) u_key_filter(
   /* input       wire            */.   clk     (clk)    ,
   /* input       wire            */.   rst_n   (rst_n)    ,
   /* input       wire [WITDH-1:0]*/.   key_in  (key_in)    ,
   /* output      wire [WITDH-1:0]*/.   key_down(key_wire)
);

uart_tx u_uart_tx(
   /*input           wire       */  .       clk       (clk)  ,
   /*input           wire       */  .       rst_n     (rst_n)  ,
   /*input           wire [7:0] */  .       tx_din    (8'hab)  ,
   /*input           wire       */  .       tx_din_vld(key_wire && ready)  ,
   /*output          wire       */  .       tx_dout   (tx)  ,
   /*output          wire       */  .       ready     (ready)      
);


endmodule //top

效果展示：
FPGA：uart原理+tx发送模块+rx接收模块,fpga开发

四、rx模块接收

/*
 * @Description: rx接收,波特率115200，系统时钟50M，传输1bit所需计数434个周期
 * @Author: Fu Yu
 * @Date: 2023-08-15 11:10:41
 * @LastEditTime: 2023-08-16 10:03:27
 * @LastEditors: Fu Yu
 */

module uart_rx (
    input           wire                clk         ,
    input           wire                rst_n       ,
    input           wire                rx_din       ,

    output          wire [7:0]          rx_dout      ,
    output          wire                rx_dout_vld  ,
    output          wire                ready           
);

parameter MAX_BIT = 50_000_000/115200;//1bit计数最大值,434

localparam  IDLE   = 4'b0001,
            START  = 4'b0010,
            DATA   = 4'b0100,
            FINISH = 4'b1000;

reg [3:0]   state_c;//现态
reg [3:0]   state_n;//次态

wire        idle_start  ;// IDLE -> START
wire        start_data  ;// START -> DATA
wire        data_finish ;// DATA -> FINISH
wire        finish_idle ;// FINFISH -> IDLE

reg			[8:0]	cnt_bit	   	;
wire				add_cnt_bit	;
wire				end_cnt_bit	;

reg			[11:0]	cnt_data	   	;
wire				add_cnt_data	;
wire				end_cnt_data	;

reg     [7:0]       rx_dout_r;

//****************************************************************
//--                状态机
//****************************************************************
always @(posedge clk or negedge rst_n) begin
    if(!rst_n) begin
        state_c <= IDLE;
    end
    else begin
        state_c <= state_n;
    end
end

always @( *) begin
    case (state_c)
        IDLE : begin
            if(idle_start) begin
                state_n = START;
            end
            else begin
                state_n = state_c;
            end
        end

        START : begin
            if(start_data) begin
                state_n = DATA;
            end
            else begin
                state_n = state_c;
            end
        end

        DATA : begin
            if(data_finish) begin
                state_n = FINISH;
            end
            else begin
                state_n = state_c;
            end
        end

        FINISH : begin
            if(finish_idle) begin
                state_n = IDLE;
            end
            else begin
                state_n = state_c;
            end
        end

        default : state_n = IDLE;
            
    endcase
end


assign idle_start  = state_c == IDLE && rx_din == 0 ;
assign start_data  = state_c == START &&  end_cnt_bit;
assign data_finish = state_c == DATA &&  end_cnt_data;
assign finish_idle = state_c == FINISH && end_cnt_bit;

//****************************************************************
//--                    计数器
//****************************************************************
//1bit计数器
always @(posedge clk or negedge rst_n)begin 
   if(!rst_n)begin
        cnt_bit <= 'd0;
    end 
    else if(add_cnt_bit)begin 
        if(end_cnt_bit)begin 
            cnt_bit <= 'd0;
        end
        else begin 
            cnt_bit <= cnt_bit + 1'b1;
        end 
    end
end 

assign add_cnt_bit = state_c == START || state_c == FINISH || state_c == DATA;
assign end_cnt_bit = add_cnt_bit && cnt_bit == MAX_BIT - 1;

//8bit计数器
always @(posedge clk or negedge rst_n)begin 
   if(!rst_n)begin
        cnt_data <= 'd0;
    end 
    else if(add_cnt_data)begin 
        if(end_cnt_data)begin 
            cnt_data <= 'd0;
        end
        else begin 
            cnt_data <= cnt_data + 1'b1;
        end 
    end
end 

assign add_cnt_data = state_c == DATA && end_cnt_bit;
assign end_cnt_data = add_cnt_data && cnt_data == 8 - 1 ;



//****************************************************************
//--            实现数据接收
//****************************************************************
always @(posedge clk or negedge rst_n) begin
    if(!rst_n) begin
        rx_dout_r <= 0;
    end
    else if(state_c == DATA && cnt_bit == MAX_BIT >> 1) begin
        rx_dout_r[cnt_data] <= rx_din;
    end
end

assign rx_dout = rx_dout_r;

assign rx_dout_vld = data_finish;

assign ready = state_c == IDLE;


endmodule //uart_rx

ip核fifo调用：

module ctrl (
    input           wire            clk                 ,
    input           wire            rst_n               ,
    input           wire [7:0]      rx_data             ,
    input           wire            rx_data_vld         ,
    input           wire            tx_ready            ,

    output          wire [7:0]      tx_data             ,
    output          wire            tx_data_vld     
);


wire  fifo_rd_empty;
wire  fifo_wr_full;




fifo	fifo_inst (
	.aclr ( ~rst_n ),

	.data ( rx_data ),
	.wrclk ( clk ),
	.wrreq ( rx_data_vld && ~fifo_wr_full ),

	.q ( tx_data ),
    .rdclk ( clk ),
	.rdreq ( tx_ready && ~fifo_rd_empty ),

	.rdempty ( fifo_rd_empty ),
	.wrfull ( fifo_wr_full )
	);


assign tx_data_vld = tx_ready && ~fifo_rd_empty ;

endmodule //ctrl

顶层模块：

module top (
    input           wire            clk         ,
    input           wire            rst_n       ,
    input           wire            key_in      ,
    input           wire            rx          ,

    output          wire            tx
);


wire        key_wire;
wire        tx_ready;
wire [7:0]  rx_data;
wire        rx_data_vld;
wire [7:0]  tx_data;
wire        tx_data_vld;


key_filter #(.WITDH(1)) u_key_filter(
   /* input       wire            */.   clk     (clk)    ,
   /* input       wire            */.   rst_n   (rst_n)    ,
   /* input       wire [WITDH-1:0]*/.   key_in  (key_in)    ,
   /* output      wire [WITDH-1:0]*/.   key_down(key_wire)
);

uart_tx u_uart_tx(
   /*input           wire       */  .       clk       (clk)  ,
   /*input           wire       */  .       rst_n     (rst_n)  ,
   /*input           wire [7:0] */  .       tx_din    (tx_data)  ,
   /*input           wire       */  .       tx_din_vld(tx_data_vld)  ,

   /*output          wire       */  .       tx_dout   (tx)  ,
   /*output          wire       */  .       ready     (tx_ready)      
);


uart_rx u_uart_rx(
   /* input           wire       */.         clk        (clk ) ,
   /* input           wire       */.         rst_n      (rst_n ) ,
   /* input           wire       */.         rx_din     (rx )  ,

   /* output          wire [7:0] */.         rx_dout    (rx_data)  ,
   /* output          wire       */.         rx_dout_vld(rx_data_vld)  ,
   /* output          wire       */.         ready      ()     
);



ctrl  u_ctrl(
    /* input           wire         */ .   clk        (clk) ,
    /* input           wire         */ .   rst_n      (rst_n) ,
    /* input           wire [7:0]   */ .   rx_data    (rx_data) ,
    /* input           wire         */ .   rx_data_vld(rx_data_vld) ,
    /* input           wire         */ .   tx_ready   (tx_ready) ,

    /* output          wire [7:0]   */ .   tx_data    (tx_data) ,
    /* output          wire         */ .   tx_data_vld(tx_data_vld)
);


endmodule //top

将rx接收模块与tx发送模块联合使用，效果如下：
FPGA：uart原理+tx发送模块+rx接收模块,fpga开发文章来源地址https://www.toymoban.com/news/detail-659804.html

到了这里，关于FPGA：uart原理+tx发送模块+rx接收模块的文章就介绍完了。如果您还想了解更多内容，请在右上角搜索TOY模板网以前的文章或继续浏览下面的相关文章，希望大家以后多多支持TOY模板网！

本文来自互联网用户投稿，该文观点仅代表作者本人，不代表本站立场。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如若转载，请注明出处： 如若内容造成侵权/违法违规/事实不符，请点击违法举报进行投诉反馈，一经查实，立即删除！

分享到：
领支付宝红包 赞助服务器费用

相关文章

  • FPGA_数码管显示UART串口接收的数据

    FPGA_数码管显示UART串口接收的数据

          实验目标 ：通过电脑调试助手向FPGA的UART串口接收模块发送数据，然后数据可以稳定显示 在数码管上。       实验目的 : 练习UART串口模块和数码管的使用。之前已经有文章详细讲解了串口和数码管的开发，故这里直接提供设计思路供大家参考。 （串口文章链接）ht

    2024年02月13日
    浏览(49)
  • 【FPGA协议篇】UART通信及其verilog实现(代码采用传参实现模块通用性，适用于快速开发)

    【FPGA协议篇】UART通信及其verilog实现(代码采用传参实现模块通用性，适用于快速开发)

    ​ 即通用异步收发器(Universal Asynchronous Receiver/Transmitter)，是一种 串行、异步、全双工 的通信协议。特点是通信线路简单，适用于远距离通信，但传输速度慢。 数据传输速率：波特率(单位:baud，波特) 常见波特率有：1200、2400、4800、19200、38400、57600等，最常用的是9600和11520

    2024年02月05日
    浏览(50)
  • FPGA实现UART通信（1）---发送数据

    FPGA实现UART通信（1）---发送数据

    1、基本概念 通用异步收发传输器，是一种异步收发传输器，在发送数据通过将并行数据转换成串行数据进行传输，在接收数据时将串行数据转换成并行数据。 串行通信分为同步串行通信和异步串行通信。同步串行通信即需要时钟的参与，通信双方需要在同一时钟的控制下，

    2024年02月04日
    浏览(45)
  • FPGA入门学习笔记（十）Vivado设计状态机实现UART多字节数据发送

    FPGA入门学习笔记（十）Vivado设计状态机实现UART多字节数据发送

    使用串口发送5个字节数据到电脑 1、ADC采样的结果为12位，如何使用串口发送 2、16位数据，如何通过串口发送 3、多个字节的数据，如何通过串口发送 UART规定，发送的数据位只能有6、7、8位，若直接修改发送位数，接收模块将不适配。 两种情况： 1、没有开始发送（上一次的

    2024年02月12日
    浏览(50)
  • FPGA串口接收解帧、并逐帧发送有效数据——1

    FPGA串口接收解帧、并逐帧发送有效数据——1

    工程实现的功能：FPGA串口接收到串口调试助手发来的数据，将其数据解帧。判断到正确的帧头和帧尾之后，将有效数据存入rx_data中；另一方面发送端将有效数据逐帧发送出去。 参考：正点原子官方FPGA串口通信实验 模块构成： 在原子哥的基础上改的代码。 添加了接收状态机

    2024年02月05日
    浏览(40)
  • FPGA串口接收解帧、并逐帧发送有效数据-2

    FPGA串口接收解帧、并逐帧发送有效数据-2

    工程实现的功能：FPGA串口接收到串口调试助手发来的数据，将其数据解帧。判断到正确的帧头和帧尾之后，将有效数据存入rx_data中；另一方面发送端将有效数据逐帧发送出去。 参考：正点原子官方FPGA串口通信实验 模块构成： 在原子哥的基础上改的代码。 添加了接收状态机

    2024年02月05日
    浏览(37)
  • FPGA Verilog 控制CAN接收发送数据帧（标准/扩展），遥控帧（标准/扩展）

    FPGA Verilog 控制CAN接收发送数据帧（标准/扩展），遥控帧（标准/扩展）

    使用Verilog接收发送，CAN数据帧和远程帧，由于条件有限，并没有实际下载到办卡上验证，只做了仿真验证，后续准确性验证后再行修改。 （1）标准数据帧： （2）扩展数据帧： （3）标准遥控帧 与数据帧的区别就是没有数据字段； （4）扩展遥控帧 系统时钟为100Mhz,CAN通信频

    2024年02月16日
    浏览(44)
  • 孩子都能学会的FPGA：第九课——多字节数据的发送和接收

    孩子都能学会的FPGA：第九课——多字节数据的发送和接收

    （原创声明：该文是 作者的原创 ，面向对象是 FPGA入门者 ，后续会有进阶的高级教程。宗旨是 让每个想做FPGA的人轻松入门 ， 作者不光让大家知其然，还要让大家知其所以然 ！每个工程作者都搭建了全自动化的仿真环境，只需要双击 top_tb.bat 文件就可以完成整个的仿真（前

    2024年02月04日
    浏览(61)
  • FPGA纯verilog实现CameraLink视频接收和发送，附带工程源码和技术支持

    FPGA纯verilog实现CameraLink视频接收和发送，附带工程源码和技术支持

    FPGA实现CameraLink视频编解码目前有两种方案： 一是使用专用编解码芯片，比如典型的DS90CR287；另一种方案是使用FPGA实现编解码，利用FPGA的serdes资源实现解串，优点是合理利用了FPGA资源，serdes资源不用白不用，缺点是操作难度大一些，对FPGA水平要求较高。 本文详细描述了F

    2024年02月07日
    浏览(49)

  • FPGA开发基础篇之一（接口篇）UART串口

    写在前面 从本文开始，将连载fpga开发基础知识，将这几年浅显的fpga开发经验整理出来，一是梳理一下这几年给别人做fpga的经历，同时也是分享给大家，也希望大牛批评指正。 一、UART串口通信基本概念 串口通信是非常基本且应用十分广泛的低速通信接口，无论是在dsp、单片

    2024年02月02日
    浏览(61)

觉得文章有用就打赏一下文章作者

支付宝扫一扫打赏

博客赞助

微信扫一扫打赏

请作者喝杯咖啡吧~博客赞助

支付宝扫一扫领取红包，优惠每天领

二维码1

领取红包

二维码2

领红包