perl 语言中 AUTOLOAD 的用法-Toy模板网

这篇具有很好参考价值的文章主要介绍了perl 语言中 AUTOLOAD 的用法。希望对大家有所帮助。如果存在错误或未考虑完全的地方，请大家不吝赐教，您也可以点击"举报违法"按钮提交疑问。

这里的 AUTOLOAD可以理解为自动加载。具体来说就是，在正常情况下，我们不能调用一个尚未定义的函数（子例程）。不过，如果在未定义函数的包中有一个名为 AUTOLOAD的函数，那么对未定义函数的调用都会路由至这个 AUTOLOAD函数，并且会为该函数提供相同的参数。因此，我们可以在 AUTOLOAD函数里面针对未定义的函数进行特殊处理，比如实现未定义的函数，然后调用该函数，就好像这个函数一直都存在一样。

比如，下面的示例程序会在你调用未定义函数时发出警告，而不是直接退出：

#!/usr/bin/env perl

sub AUTOLOAD {
	our $AUTOLOAD;
	warn "You attempt to call an undefined function: $AUTOLOAD\n";
}

&foo; # $AUTOLOAD will be set to main::foo
print "Exit normally ...\n"

运行结果如下所示：

$ ./autoload.pl 
You attempt to call an undefined function: main::foo
Exit normally ...

下面是一个更加实用的例子，即我们在 AUTOLOAD中实现未定义的函数：

#!/usr/bin/env perl

sub AUTOLOAD {
	my $name = our $AUTOLOAD;
	*$AUTOLOAD = sub { print "calling function $name(@_)\n"; };
	goto &$AUTOLOAD;
}

foo(30);
goo(40);
hoo(50);

运行结果如下所示：

$ ./autoload_2.pl 
calling function main::foo(30)
calling function main::goo(40)
calling function main::hoo(50)

在OpenSSL项目中的很多地方都有用到 perl语言，它主要负责项目建构和汇编代码的生成工作。其中，在生成加解密算法汇编优化代码的 perl脚本中，有很多架构都用到了 AUTOLOAD机制去简化汇编指令的书写。下面看一个 OpenSSL中 x86实现的例子，从 crypto/chacha/asm/chacha-x86_64.pl文件中节选出如下代码：

#!/usr/bin/env perl

sub AUTOLOAD()          # thunk [simplified] 32-bit style perlasm
{ my $opcode = $AUTOLOAD; $opcode =~ s/.*:://;
  my $arg = pop;
    $arg = "\$$arg" if ($arg*1 eq $arg);
    $code .= "\t$opcode\t".join(',',$arg,reverse @_)."\n";
}

@x=("%eax","%ebx","%ecx","%edx",map("%r${_}d",(8..11)),
    "%nox","%nox","%nox","%nox",map("%r${_}d",(12..15)));
@t=("%esi","%edi");

sub ROUND {                     # critical path is 24 cycles per round
my ($a0,$b0,$c0,$d0)=@_;
my ($a1,$b1,$c1,$d1)=map(($_&~3)+(($_+1)&3),($a0,$b0,$c0,$d0));
my ($xc,$xc_)=map("\"$_\"",@t);
my @x=map("\"$_\"",@x);

        (
        "&add   (@x[$a0],@x[$b0])",     # Q1
        "&xor   (@x[$d0],@x[$a0])",
        "&rol   (@x[$d0],16)",
         "&add  (@x[$a1],@x[$b1])",     # Q2
         "&xor  (@x[$d1],@x[$a1])",
         "&rol  (@x[$d1],16)",

        "&add   ($xc,@x[$d0])",
        "&xor   (@x[$b0],$xc)",
        "&rol   (@x[$b0],12)",
         "&add  ($xc_,@x[$d1])",
         "&xor  (@x[$b1],$xc_)",
         "&rol  (@x[$b1],12)",
		)
}

foreach (&ROUND(0, 4, 8,12)) { eval; }
foreach (&ROUND(0, 5,10,15)) { eval; }

print "$code\n";

从上面的代码可以看到，表面上，add()，xor()，rol()这些函数并没有被声明和实现，但该脚本定义了 AUTOLOAD函数，并在 AUTOLOAD函数中进行了统一的处理，比如，将 &add(xx, yy)函数调用转换为了 add yy,xx指令字符串。
因此，上述脚本的运行结果如下所示：文章来源地址https://www.toymoban.com/news/detail-680666.html

$ ./autoload_3.pl 
	add	%r8d,%eax
	xor	%eax,%r12d
	rol	$16,%r12d
	add	%r9d,%ebx
	xor	%ebx,%r13d
	rol	$16,%r13d
	add	%r12d,%esi
	xor	%esi,%r8d
	rol	$12,%r8d
	add	%r13d,%edi
	xor	%edi,%r9d
	rol	$12,%r9d
	add	%r9d,%eax
	xor	%eax,%r15d
	rol	$16,%r15d
	add	%r10d,%ebx
	xor	%ebx,%r12d
	rol	$16,%r12d
	add	%r15d,%esi
	xor	%esi,%r9d
	rol	$12,%r9d
	add	%r12d,%edi
	xor	%edi,%r10d
	rol	$12,%r10d