Unity中Shader雾效的实现方法一-Toy模板网

这篇具有很好参考价值的文章主要介绍了Unity中Shader雾效的实现方法一。希望对大家有所帮助。如果存在错误或未考虑完全的地方，请大家不吝赐教，您也可以点击"举报违法"按钮提交疑问。

前言

Unity中Shader雾效的实现方法一，按照之前的公式, 我们自己来实现一下

Unity中Shader雾效的原理

基于上一篇文章继续：

Unity中Shader的雾效

一、在片元着色器中使用如下公式计算

最终的颜色 = lerp(雾效颜色，物体颜色，雾效混合因子)

不管是什么类型的雾，这个雾效的公式都是统一的

1、获取雾效颜色

unity_FogColor

2、物体的颜色一般通过纹理采样得到，此处用 1 代替测试

3、获取雾效混合因子（由雾的距离和雾的浓度决定）

雾效混合因子是由，之前的三个雾效衰减公式计算得到的

Unity中Shader雾效的原理

因为在片元着色器中计算雾效需要使用该因子
所以在 v2f 中定义一个 TEXCOORD 类型的 float 变量 fogFactor

float fogFactor : TEXCOORD1;

二、在顶点着色器中，计算不同类型的雾效混合因子（在顶点着色器计算节省性能）

Unity预定义好方便我们计算的四维变量 unity_FogParams

unity unity_fogparams,Unity,unity,游戏引擎

1、计算线性雾的雾效混合因子

unity unity_fogparams,Unity,unity,游戏引擎

获取 z ：这个z是摄像机到物体的距离
z = （用摄像机的世界坐标 - 顶点的世界坐标）的模长
计算需要准备：
摄像机的世界坐标：_WorldSpaceCameraPos
顶点的世界坐标:mul(unity_ObjectToWorld,v.vertex)

float z = length(_WorldSpaceCameraPos - worldPos);

获取 start 和 end
上面的公式可以等价为：
fogFactor
= (end - z) / (end - start)
= (end / (end - start)) + z * (-1 / (end - start))
使用Unity预定义的公式后：
= unity_FogParams.w + z * unity_FogParams.z ;

//(end - z) / (end - start)= (end / (end - start)) + z * (-1 / (end - start))
o.fogFactor = z * unity_FogParams.z + unity_FogParams.w;

效果：
unity unity_fogparams,Unity,unity,游戏引擎

2、计算指数雾1 的雾效混合因子

unity unity_fogparams,Unity,unity,游戏引擎

fogFactor
= exp2(-density * z)
使用Unity预定义的公式后：
= exp2(-unity_FogParams.y * z)

//exp2(-density * z)
o.fogFactor = exp2(-unity_FogParams.y * z);

效果：
unity unity_fogparams,Unity,unity,游戏引擎

3、计算指数雾2 的雾效混合因子

unity unity_fogparams,Unity,unity,游戏引擎
fogFactor
= exp2(-(density * z)^2)
使用Unity预定义的公式后：
= exp2(-(unity_FogParams.x * z)^2)

//exp2(-(density * z)^2)
float density = unity_FogParams.x * z;
o.fogFactor = exp2(-density * density);

效果：
unity unity_fogparams,Unity,unity,游戏引擎文章来源地址https://www.toymoban.com/news/detail-757109.html

三、最终测试代码

//unity的雾效
//雾效的实现方法一
Shader "MyShader/P1_9_3"
{
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fog
            #include "UnityCG.cginc"
           

            struct appdata
            {
                float4 vertex : POSITION;
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                float fogFactor : TEXCOORD1;
            };
            
            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                float4 worldPos = mul(unity_ObjectToWorld,v.vertex);
                float z = length(_WorldSpaceCameraPos - worldPos);

                #if defined(FOG_LINEAR)
                    //(end - z) / (end - start)= (end / (end - start)) + z * (-1 / (end - start))
                    o.fogFactor = z * unity_FogParams.z + unity_FogParams.w;
                #elif defined(FOG_EXP)
                    //exp2(-density * z)
                    o.fogFactor = exp2(-unity_FogParams.y * z);
                #elif defined(FOG_EXP2)
                    //exp2(-(density * z)^2)
                    float density = unity_FogParams.x * z;
                    o.fogFactor = exp2(-density * density);
                #endif
                
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 c = 0;
                #if defined(FOG_LINEAR) || defined(FOG_EXP) || defined(FOG_EXP2)
                    c = lerp(unity_FogColor,c,i.fogFactor);
                #endif
                
                return c;
            }
            ENDCG
        }
    }
}

到了这里，关于Unity中Shader雾效的实现方法一的文章就介绍完了。如果您还想了解更多内容，请在右上角搜索TOY模板网以前的文章或继续浏览下面的相关文章，希望大家以后多多支持TOY模板网！