NodeMCU ESP8266 的定时器使用以及非堵塞程序的实现-Toy模板网

这篇具有很好参考价值的文章主要介绍了NodeMCU ESP8266 的定时器使用以及非堵塞程序的实现。希望对大家有所帮助。如果存在错误或未考虑完全的地方，请大家不吝赐教，您也可以点击"举报违法"按钮提交疑问。

1 前言

本文会介绍ESP8266的定时器使用方法，传统的延时函数存在堵塞占用CPU的问题，后面对于系统中有延时以及定时的功能要求，怎么做才能是系统更加高效合理，我们来进一步学习一下。

2 延时

通常我们使用delay()函数来进行一定时间的延时，这个函数接收一个Int型的传入参数，来制定需要延时多少时间，具体如下；

delay(time in milliseconds);

如果我们调用delay(1000)，则系统会在这里延时1秒钟，这是一个堵塞的函数，具体如下程序所示；

do_action_a();
delay(1000);
do_action_b();

必须在执行完do_action_a之后，并且等待1秒钟（1000毫秒），
do_action_b才能执行。
delay函数会占用CPU，阻止程序执行其他任何操作，直到完成当前的延时程序。

具体如下图所示；

esp8266定时开关,ESP8266学习教程⭐⭐,ESP8266,嵌入式硬件,单片机,物联网

所以大多数项目中，我们应该避免使用延迟函数，避免堵塞系统，死占CPU的做法，当然具体要根据实际情况来决定,那么这里应该怎么做，才能改成非堵塞的程序呢？

这里可能用到millis，下面继续讨论millis()。

3 定时器

ESP8266 中有两个定时器 Timer0 和 Timer1，其中一个定时器用于其 WiFi 功能。我们只有一个计时器可以工作。为了避免崩溃问题，建议使用 Ticker 而不是 Timer。下面会做介绍。

对于非堵塞函数，我们可以先看看millis()函数，它可以获取自程序首次启动以来经过的毫秒数。具体函数原型如下所示；

unsigned long TimeStamp = millis();

3.1 如何使用

那么如何使用这个函数进行非堵塞的程序设计呢？

具体如下所示；


unsigned long preTimeStamp = 0;        // will store last 
const long period = 1000;    

void loop() {

  unsigned long TimeStamp = millis();  

  if (TimeStamp - preTimeStamp >= period) {

    preTimeStamp = TimeStamp;
    //Do Action
    //TODO

  }
}

上述程序中，通过判断当前的时间戳与上一次时间戳的差值，如果经过了period毫秒，则会进入if语句中执行相应功能的程序。

3.2 示例代码

下面写一段使用millis()函数，进行LED闪烁的程序；


const int ledPin =  26;      // the number of the LED pin

int ledState = LOW;             // ledState used to set the 

unsigned long previousMillis = 0;        // will store last 
const long interval = 1000;           // interval at which 

void setup() {
  pinMode(ledPin, OUTPUT);
}

void loop() {

  unsigned long currentMillis = millis();

  if (currentMillis - previousMillis >= interval) {

    previousMillis = currentMillis;

    if (ledState == LOW) {
      ledState = HIGH;
    } else {
      ledState = LOW;
    }

    digitalWrite(ledPin, ledState);
  }
}

让我们仔细看看程序，首先这里没有使用delay()函数（使用了millis()函数进行替代；

这个程序通过获取当前millis和上一个millis的差值，如果这个差值大于我们设定的时间间隔（当前程序中是 1000 毫秒），则程序可以进入if语句中执行相应的程序，并且更新millis；

if (currentMillis - previousMillis >= interval) {
  // 保持新的时间戳到 previousMillis 变量中
  previousMillis = currentMillis;
  (...)

这一段程序是非堵塞的，所以if语句外的代码都可以正常工作，

4 Ticker库的使用

Ticker 是在一定周期内重复调用函数的库。Ticker 是 os_timer每个周期去调用一个函数。

我们可以拥有任意数量的调用函数，单身内存是唯一的限制。注册的回调越多，开销越大。

Attach 函数有两个变量：Attach和Attach_ms。

第一个周期以秒为单位;
第二个周期以毫秒为单位;

下面是一个每间隔1秒，闪烁LED的程序，具体如下所示；

#include <ESP8266WiFi.h>
#include <Ticker.h>  //Ticker库

Ticker blinker;

#define LED 2  //板载LED

void changeState()
{
  digitalWrite(LED, !(digitalRead(LED)));  //变化LED的状态
}

void setup()
{
    Serial.begin(115200);
    Serial.println("");

    pinMode(LED,OUTPUT);

    blinker.attach(1, changeState); //每过1秒，会执行changeState函数
}

void loop()
{
    //执行其他任务
}

5 硬件定时器

硬件 Timer0由 WiFi 功能使用。我们只能使用Timer1。使用计时器而不是 Ticker 可以提供精确计时的优势，并且我们可以在微秒内获得定时器中断。

下面程序会涉及到较多的基础概念，如果感觉较难理解，可以暂时忽略，具体程序如下所示；

#include <ESP8266WiFi.h>
#include <Ticker.h>

Ticker blinker;

#define LED 2  //On board LED

void ICACHE_RAM_ATTR onTimerISR(){
    digitalWrite(LED,!(digitalRead(LED)));  //反转LED引脚电平
    timer1_write(600000);//12us
}

void setup()
{
    Serial.begin(115200);
    Serial.println("");

    pinMode(LED,OUTPUT);

    //初始化 Ticker 间隔 0.5s
    timer1_attachInterrupt(onTimerISR);
    timer1_enable(TIM_DIV16, TIM_EDGE, TIM_SINGLE);
    timer1_write(600000); //120000 us
}

void loop()
{
}