第 9 章：压缩和存储
Hive不会强制要求将数据转换成特定的格式才能使用。利用Hadoop的InputFormat API可以从不同数据源读取数据，使用OutputFormat API可以将数据写成不同的格式输出。
对数据进行压缩虽然会增加额外的CPU开销，但是会节约客观的磁盘空间，并且通过减少内存的数据量而提高I/O吞吐量会更加提高网络传输性能。
原则上Hadoop的job时I/O密集型的话就可以采用压缩可以提高性能，如果job是CPU密集型的话，那么使用压缩可能会降低执行性能。
9.1 Hadoop压缩配置
9.1.1 MR支持的压缩编码
| 压缩格式 | 算法 | 文件扩展名 | 是否可切分 |
|---|---|---|---|
| Deflate | Deflate | .deflate | 否 |
| Gzip | Deflate | .gz | 否 |
| Bzip2 | Bzip2 | .bz2 | 是 |
| Lzo | Lzo | .lzo | 是 |
| Snappy | Snappy | .snappy | 否 |
为了支持多种压缩/解压缩算法，Hadoop引入了编码/解码器，如下表所示：
| 压缩格式 | 对应的编码/解码器 |
|---|---|
| Deflate | org.apache.hadoop.io.compress.DefaultCodec |
| Gzip | org.apache.hadoop.io.compress.GzipCodec |
| Bzip2 | org.apache.hadoop.io.compress.BZip2Codec |
| Lzo | com.hadoop.compression.lzo.LzopCodec |
| Snappy | org.apache.hadoop.io.compress.SnappyCodec |
为什么需要这么多的压缩方案呢？
每一个压缩方案都在压缩和解压缩速度和压缩率间进行权衡。
如下是压缩性能的比较
| 压缩算法 | 原始文件大小 | 压缩文件大小 | 压缩速度 | 解压速度 |
|---|---|---|---|---|
| gzip | 8.3GB | 1.8GB | 17.5MB/s | 58MB/s |
| bzip2 | 8.3GB | 1.1GB | 2.4MB/s | 9.5MB/s |
| LZO | 8.3GB | 2.9GB | 49.3MB/s | 74.6MB/s |
9.1.2 压缩参数配置
要在Hadoop中启用压缩，可以配置如下参数（mapred-site.xml文件中）：
| 参数 | 默认值 | 阶段 | 建议 |
|---|---|---|---|
| io.compression.codecs （在core-site.xml中配置） | org.apache.hadoop.io.compress.DefaultCodec, org.apache.hadoop.io.compress.GzipCodec, org.apache.hadoop.io.compress.BZip2Codec,org.apache.hadoop.io.compress.Lz4Codec | 输出压缩 | Hadoop使用文件扩展名判断是否支持某种编解码器 |
| mapreduce.map.output.compress | false | mapper输出 | 这个参数为true启动压缩 |
| mapreduce.map.output.compress.codec | org.apache.hadoop.io.compress.DefaultCodec | mapper输出 | 使用LZO、LZ4或snappy编解码器在此阶段压缩数据 |
| mapreduce.output.fileoutputformat.compress | false | reducer输出 | 这个参数设为true启动压缩 |
| mapreduce.output.fileoutputformat.compress.codec | org.apache.hadoop.io.compress. DefaultCodec | reducer输出 | 使用标准工具或者编码器，如gzip和bzip2 |
| mapreduce.output.fileoutputformat.compress.type | RECORD | reducer输出 | SequenceFile输出使用的压缩类型：NONE和BLOCK |
9.2 开启Map输出阶段压缩
开启map输出阶段压缩可以减少job中map和Reduce task间数据传输量。
1、具体配置如下：
1）开启hive中间传输数据压缩功能
set hive.exec.compress.intermediate =true;
2）开启mapreduce中map输出压缩功能
set mapreduce.map.output.compress=true;
3）设置mapreduce中map输出数据的压缩方式
set mapreduce.map.output.compress.codec= org.apache.hadoop.io.compress.SnappyCodec;
4）执行查询语句
select count(ename) name from emp;
5）观察yarn执行的job的map阶段日志可看到如下内容
9.3 开启Reduce输出阶段压缩
当Hive将输出写入到表中时可以通过属性hive.exec.compress.output，对输出内容进行压缩。当hive.exec.compress.output=false，这样输出就是非压缩的纯文本文件了。将hive.exec.compress.output=true，来开启输出结果压缩功能。
1、设置步骤如下：
1）开启hive最终输出数据压缩功能
set hive.exec.compress.output=true;
2）开启mapreduce最终输出数据压缩
set mapreduce.output.fileoutputformat.compress=true;
3）设置mapreduce最终数据输出压缩方式
set mapreduce.output.fileoutputformat.compress.codec = org.apache.hadoop.io.compress.SnappyCodec;
4）设置mapreduce最终数据输出压缩为块压缩
set mapreduce.output.fileoutputformat.compress.type=BLOCK;
5）测试以下输出结果是否为压缩文件
insert overwrite local directory
'/opt/module/hive/datas/distribute-result' select * from emp distribute by deptno sort by empno desc;
6）查看目录/opt/module/hive/datas/distribute-result下文件
distribute-result]$ ll
总用量 4
-rw-r--r--. 1 atguigu atguigu 493 10月 21 22:56 000000_0.snappy
9.4 文件存储格式
Hive支持的存储数据的格式主要有：TEXTFILE、SEQUENCEFILE、ORC、PARQUET。
9.4.1 列式存储和行式存储
如图所示，左边为逻辑表，右边第一个是行式存储，第二个式列式存储。
9.4.2 TextFile格式
默认格式，数据不做压缩，磁盘开销大，数据解析开销大。
可结合Gzip，Bzip2使用，但使用Gzip这种方式，hive不会对数据进行切分，从而无法对数据进行并行操作。
9.4.3 Orc格式
Orc是Hive 0.11版里引入的新的存储格式。
如下图所示可以看到每个Orc文件由1个或多个stripe组成，每个stripe一般为HDFS的块大小，每一个stripe包含多条记录，这些记录按照列进行独立存储，对应到Parquet中的row group的概念。每个Stripe里有三部分组成，分别是Index Data, Row Data,Stripe Footer；
1、Index Data：一个轻量级的index，默认是每隔1W行做一个索引。这里做的索引应该只是记录某行的各字段在Row Data中的offset。
2、Row Data：存的是具体的数据，先取部分行，然后对这些行按列进行存储。对每个列进行了编码，分成多个Stream来存储。
3、Stripe Footer：存的是各个Stream的类型，长度等信息。每个文件有一个File Footer，这里面存的是每个Stripe的行数，每个Column的数据类型信息等；每个文件的尾部是一个PostScript，这里面记录了整个文件的压缩类型以及FileFooter的长度信息等。在读取文件时，会seek到文件尾部读PostScript，从里面解析到File Footer长度，再读FileFooter，从里面解析到各个Stripe信息，再读各个Stripe，即从后往前读。
9.4.4 Parquet格式
Parquet文件是以二进制方式存储的，所以是不可以直接读取的。文件中包括该文件的数据和元数据，因此Parquet格式文件是自解析的。
1、行组（Row Group）：每一个行组包含一定的行数，在一个HDFS文件中至少存储一个行组，类似于orc的stripe的概念。
2、列块（Column Chunk）：在一个行组中每一列保持在一个列块中，行组中的所有列连续的存储在这个行组文件中。一个列块中的值都是相同类型的，不同列块可能使用不同的算法进行压缩。
3、页（Page）：每一个列块划分为多个页，一个页是最小的编码的单位，在同一个列块的不同页可能使用不同的编码方式。
通常情况下，在存储Parquet数据的时候会按照Block大小设置行组的大小，由于一般情况下每一个Mapper任务处理数据的最小单位是一个Block，这样可以把每一个行组由一个Mapper任务处理，增大任务执行并行度。
上图展示了一个Parquet文件的内容，一个文件中可以存储多个行组，文件的首位都是该文件的Magic Code，用于校验它是否是一个Parquet文件，Footer length记录了文件元数据的大小，通过该值和文件长度可以计算出元数据的偏移量，文件的元数据中包括每一个行组的元数据信息和该文件存储数据的Schema信息。除了文件中每一个行组的元数据，每一页的开始都会存储该页的元数据，在Parquet中，有三中类型的页：数据页、字典页和索引页。数据页用于存储当前行组中该列的值，字典页存储该列值的编码字典，每一个列块中最多包含一个字典页，索引页用来存储当前行组下该列的索引，目前Parquet中还不支持索引页。
9.4.5 主流存储文件格式对比
1、TextFile
1)创建log_text，设置其存储数据格式为TEXTFILE
create table log_text (
track_time string,
url string,
session_id string,
referer string,
ip string,
end_user_id string,
city_id string
)
row format delimited fields terminated by '\t'
stored as textfile;
2）向表中加载数据
load data local inpath '/opt/module/hive/datas/log.data' into table log_text ;
3）查看表中数据大小
dfs -du -h /user/hive/warehouse/log_text;
18.1 M 54.4 M /user/hive/warehouse/log_text/log.data
4）采用TextFile格式存储，文件大小为18.1M
2、ORC
1）创建表loc_orc，存储数据格式是ORC
create table log_orc(
track_time string,
url string,
session_id string,
referer string,
ip string,
end_user_id string,
city_id string
)
row format delimited fields terminated by '\t'
stored as orc
tblproperties("orc.compress"="NONE"); // 由于ORC格式时自带压缩的，这设置orc存储不使用压缩
2）向表中插入数据
insert into table log_orc select * from log_text ;
3）查看表中数据大小
dfs -du -h /user/hive/warehouse/log_orc/ ;
7.7 M 23.1 M /user/hive/warehouse/log_orc/000000_0
4）采用ORC（非压缩）格式存储，文件大小为7.7M
3、Parquet
1）创建表log_parquet，设置其存储数据格式为parquet
create table log_parquet(
track_time string,
url string,
session_id string,
referer string,
ip string,
end_user_id string,
city_id string
)
row format delimited fields terminated by '\t'
stored as parquet ;
2）向表中插入数据
insert into table log_parquet select * from log_text ;
3）查看表中数据大小
dfs -du -h /user/hive/warehouse/log_parquet/ ;
13.1 M 39.3 M /user/hive/warehouse/log_parquet/000000_0
4）采用Parquet格式存储，文件大小为13.1M
4、存储文件的对比总结：
ORC>Parquet>textFile
5、存储文件的查询速度测试：
1）TextFile
insert overwrite local directory '/opt/module/hive/data/log_text' select substring(url,1,4) from log_text ;
No rows affected (10.522 seconds)
2）ORC
insert overwrite local directory '/opt/module/hive/data/log_orc' select substring(url,1,4) from log_orc ;
No rows affected (11.495 seconds)
3）Parquet
insert overwrite local directory '/opt/module/hive/data/log_parquet' select substring(url,1,4) from log_parquet ;
No rows affected (11.445 seconds)
存储文件的查询速度总结：查询速度相近
9.5 存储和压缩结合
9.5.1 测试存储和压缩
1、创建一个ZLIB压缩的ORC存储方式
1）创建表log_orc_zlib表，设置其使用ORC文件格式，并使用ZLIB压缩
create table log_orc_zlib(
track_time string,
url string,
session_id string,
referer string,
ip string,
end_user_id string,
city_id string
)
row format delimited fields terminated by '\t'
stored as orc
tblproperties("orc.compress"="ZLIB");
2）向表log_orc_zlib插入数据
insert into log_orc_zlib select * from log_text;
3）查看插入后数据文件大小
dfs -du -h /user/hive/warehouse/log_orc_zlib/ ;
2.8 M 8.3 M /user/hive/warehouse/log_orc_zlib/000000_0
4）采用ORC文件格式，并使用ZLIB压缩时，文件大小2.8M
2、创建一个SNAPP压缩的ORC存储方式
1）创建表log_orc_snappy表，设置其使用ORC文件格式，并使用snappy压缩
create table log_orc_snappy(
track_time string,
url string,
session_id string,
referer string,
ip string,
end_user_id string,
city_id string
)
row format delimited fields terminated by '\t'
stored as orc
tblproperties("orc.compress"="SNAPPY");
2）插入数据
insert into log_orc_snappy select * from log_text;
3）查看插入后数据
dfs -du -h /user/hive/warehouse/log_orc_snappy/ ;
3.7 M 11.2 M /user/hive/warehouse/log_orc_snappy/000000_1
4）采用ORC文件格式，并使用SNAPPY压缩时，文件大小3.7M
ZLIB比Snappy压缩的还小。原因是ZLIB采用的是deflate压缩算法。比snappy压缩的压缩率高。
3、创建一个SNAPPY压缩的parquet存储方式
1）创建表log_parquet_snappy，设置其使用Parquet文件格式，并使用SNAPPY压缩
create table log_parquet_snappy(
track_time string,
url string,
session_id string,
referer string,
ip string,
end_user_id string,
city_id string
)
row format delimited fields terminated by '\t'
stored as parquet
tblproperties("parquet.compression"="SNAPPY");
2）向表log_parquet_snappy插入数据
insert into log_parquet_snappy select * from log_text;
3）查看插入后数据文章来源：https://www.toymoban.com/news/detail-798178.html
dfs -du -h /user/hive/warehouse/log_parquet_snappy / ;
6.4 M 19.2 M /user/hive/warehouse/log_parquet_snappy/000000_0
4）采用Parquet文件格式，并使用SNAPPY压缩时，文件大小6.4MB
4、存储方式和压缩总结
在实际的项目开发当中：
1）hive表的数据存储格式一般选择：orc或parquet
2）压缩方式一般选择snappy，lzo文章来源地址https://www.toymoban.com/news/detail-798178.html
到了这里，关于大数据开发之Hive（压缩和存储）的文章就介绍完了。如果您还想了解更多内容，请在右上角搜索TOY模板网以前的文章或继续浏览下面的相关文章，希望大家以后多多支持TOY模板网！
