大数据开发之Hive（企业级调优）-Toy模板网

这篇具有很好参考价值的文章主要介绍了大数据开发之Hive（企业级调优）。希望对大家有所帮助。如果存在错误或未考虑完全的地方，请大家不吝赐教，您也可以点击"举报违法"按钮提交疑问。

第 10 章：企业级调优

创建测试用例
1、建大表、小表和JOIN后表的语句

// 创建大表
create table bigtable(id bigint, t bigint, uid string, keyword string, url_rank int, click_num int, click_url string) row format delimited fields terminated by '\t';
// 创建小表
create table smalltable(id bigint, t bigint, uid string, keyword string, url_rank int, click_num int, click_url string) row format delimited fields terminated by '\t';
// 创建JOIN后表
create table jointable(id bigint, t bigint, uid string, keyword string, url_rank int, click_num int, click_url string) row format delimited fields terminated by '\t';

2、分别向大表和小表中导入数据

load data local inpath '/opt/module/hive/datas/bigtable' into table bigtable;
load data local inpath '/opt/module/hive/datas/smalltable' into table smalltable;

10.1 执行计划（Explain）

1、基本语法

EXPLAIN [EXTENDED | DEPENDENCY | AUTHORIZATION] query

2、实例操作
1）查看下面这条语句的执行计划
（1）没有生成MR任务的

explain select * from emp;

大数据开发之Hive（企业级调优）,大数据,hive,hadoop
（2）有生成MR任务的

explain select deptno, avg(sal) avg_sal from emp group by deptno;

大数据开发之Hive（企业级调优）,大数据,hive,hadoop
2）查看详细执行计划

explain extended select * from emp;
explain extended select deptno, avg(sal) avg_sal from emp group by deptno;

10.2 HQL语法优化

10.2.1 列裁剪和分区裁剪

在生产环境中，会面临列很多或者数据量很大时，如果使用select * 或者不指定分区进行全列或者全表扫描时效率很低。Hive在读取数据时，可以只读取查询中所需要的列，忽略其它的列，这样做可以节省读取开销（中间表存储开销和数据整合开销）
1、列裁剪：在查询时只读取需要的列
2、分区裁剪：在查询时只读取需要的分区

10.2.2 Group By

1、介绍：默认情况下，Map阶段同一Key数据分发给一个reduce，当一个key数据过大时就倾斜了。
大数据开发之Hive（企业级调优）,大数据,hive,hadoop
并不是所有的聚合操作都需要在Reduce端完成，很多聚合操作都可以先在Map端进行部分聚合，最后在Reduce端得出最终结果。
2、进行参数设置
1）开始Map端聚合参数设置
（1）是否在Map端进行聚合，默认为True()

set hive.map.aggr = true

（2）在Map端进行聚合操作的条目数量

set hive.groupby.mapaggr.checkinterval = 100000

（3）在数据倾斜的时候进行负载均衡（默认是false）

set hive.groupby.skewindata = true

（4）当开启数据负载均衡时，生成的查询计划会有两个MRJob。
第一个MRJob中，Map的输出结果会随机分布到Reduce中，每个Reduce做部分聚合操作，并输出结果，这样处理的结果是相同的Group By Key有可能被分发到不同的Reduce中，从而达到负载均衡的目的；
第二个MRJob再根据预处理的数据结果按照Group By Key分布到Reduce中（这个过程可以保证相同的Group By Key被分布到同一个Reduce中），最后完成最终的聚合操作。
3、案例
1）优化前

select deptno from emp group by deptno;
Stage-Stage-1: Map: 1  Reduce: 5   Cumulative CPU: 23.68 sec   HDFS Read: 19987 HDFS Write: 9 SUCCESS
Total MapReduce CPU Time Spent: 23 seconds 680 msec
OK
deptno
10
20
30

2）优化以后

set hive.groupby.skewindata = true;
explain select deptno from emp group by deptno;
Stage-Stage-1: Map: 1  Reduce: 5   Cumulative CPU: 28.53 sec   HDFS Read: 18209 HDFS Write: 534 SUCCESS
Stage-Stage-2: Map: 1  Reduce: 5   Cumulative CPU: 38.32 sec   HDFS Read: 15014 HDFS Write: 9 SUCCESS
Total MapReduce CPU Time Spent: 1 minutes 6 seconds 850 msec
OK
deptno
10
20
30

10.2.3 CBO优化

join的时候表的顺序的关系：前面的表会被加载到内存中。后面的表进行磁盘扫描

select a.*, b.*, c.* from a join b on a.id = b.id join c on b.tt = c.tt;

Hive自0.14.0开始，加入了一项“Cost based Optimizer”来对HQL执行计划进行优化，这个功能通过“hive.cbo.enable”来开启。在Hive1.1.0之后，这个属性是默认开启的，它可以自动优化HQL中多个Join的顺序，并选择合适的Join算法。
CBO，成本优化器，代价最小的执行计划就是最好的执行计划。传统的数据块，成本优化器做出最优化的执行计划是依据统计信息来计算的。
Hive的成本优化器也一样，Hive在提供最终执行前，优化每个查询的执行逻辑和物理执行计划。这些优化工作是交给底层来完成的。根据查询成本执行进一步的优化，从而产生潜在的不同决策：如何排序连接，执行哪种类型的连接，并行度等等。
要使用基于成本的优化（也称为CBO）,请在查询开始设置一下参数：

set hive.cbo.enable=true;
set hive.compute.query.using.stats=true;
set hive.stats.fetch.column.stats=true;
set hive.stats.fetch.partition.stats=true;（Removed In: Hive 3.0.0 with HIVE-17932）

10.2.4 谓词下推

1、谓词下推：保证结果正确的前提下，将SQL语句中的where谓词逻辑都尽可能提前执行，减少下游处理的数据量。对应逻辑优化器是PredicatePushDown，配置项为hive.optimize.ppd，默认值为true。
2、什么是谓词：where后面的条件
3、优势：通过谓词下推，过滤条件将在map端提前执行，减少了map端的输出，降低了数据IO，节约资源，提升性能。
4、实例：
1）打开谓词下推优化属性

set hive.optimize.ppd = true; #谓词下推，默认是true

2）查看先关联两张表，再用where条件过滤的执行计划

explain select o.id from bigtable b join bigtable o  on o.id = b.id where o.id <= 10;

3）查看子查询后，再关联表的执行计划

explain select b.id from bigtable b
join (select id from bigtable where id <= 10) o on b.id = o.id;

（1）测试先关联两张表，再用where条件过滤

select o.id from bigtable b
join bigtable o on  o.id = b.id
where o.id <= 10;

Time taken: 34.406 seconds, Fetched: 100 row(s)
（2）通过子查询后，再关联表

select b.id from bigtable b
join (select id from bigtable where id <= 10 ) o on b.id = o.id;

Time taken: 30.058 seconds, Fetched: 100 row(s)

10.2.5 MapJoin

MapJoin是将Join双方比较小的表直接分发给各个Map进程的内存中，在Map进程中进行Join操作，这样就不用进行Reduce步骤，从而提高了速度。如果不指定MapJoin或者不符合MapJoin的条件，那么Hive解析器会将Join操作转换成Common Join，即：在Reduce阶段完成Join。容易发生数据倾斜。可以用MapJoin把小表全部加载到内存在Map端进行Join，避免Reducer处理。
1、开启MapJoin参数设置
1）设置自动选择MapJoin

set hive.auto.convert.join=true; #默认为true

2）大表小表的阈值设置（默认25M以下认为是小表）

set hive.mapjoin.smalltable.filesize=25000000;

2、MapJoin工作机制
MapJoin是将Join双方比较小的表直接分发到各个Map进程的内容中，在Map进程中进行Join操作，这样就不用进行Reduce步骤，从而提高了速度。
3、实操：
1）开启MapJoin功能

hive(default)> set hive.auto.convert.join = true; //默认为true

2）执行小表JOIN大表功能
注意：此时小表（左连接）作为主表，所有数据都要写出去，因此此时会走reduce，mapjoin失效

Explain
select b.id, b.t, b.uid, b.keyword, b.url_rank, b.click_num, b.click_url
from smalltable s
left join bigtable b
on s.id = b.id;

3）执行大表JOIN小表语句

Explain
select b.id, b.t, b.uid, b.keyword, b.url_rank, b.click_num, b.click_url
from bigtable b
left join smalltable s
on b.id = s.id;

10.2.6 大表、大表SMB JOIN（重点）

1、SMB：sort merge bucket join
2、实例
1）对照案例，普通大表join
（1）创建第二张大表bigtable2，并加载数据

create table bigtable2(
    id bigint,
    t bigint,
    uid string,
    keyword string,
    url_rank int,
    click_num int,
    click_url string)
row format delimited fields terminated by '\t';
load data local inpath '/opt/module/hive/datas/bigtable' into table bigtable2;

（2）测试大表直接JOIN

insert overwrite table jointable
select b.id, b.t, b.uid, b.keyword, b.url_rank, b.click_num, b.click_url
from bigtable s
join bigtable2 b
on b.id = s.id;

2）SMB案例，分桶大表join
（1）创建分桶表1 -> bigtable_buck1，桶的个数不要超过可用cpu的核数

create table bigtable_buck1(
    id bigint,
    t bigint,
    uid string,
    keyword string,
    url_rank int,
    click_num int,
    click_url string)
clustered by(id) 
sorted by(id)
into 6 buckets   -- 桶的个数和CPU核数和Reduce数需要一致
row format delimited fields terminated by '\t';
insert into bigtable_buck1 select * from bigtable;

（2）创建分桶表2 -> bigtable_buck2，桶的个数是bigtable_buck1的倍数关系，这里取一倍

create table bigtable_buck2 like bigtable_buck1;
insert into bigtable_buck2 select * from bigtable;

（3）设置参数，开启SMB

set hive.optimize.bucketmapjoin = true;
set hive.optimize.bucketmapjoin.sortedmerge = true;
set hive.input.format=org.apache.hadoop.hive.ql.io.BucketizedHiveInputFormat;

（4）测试SMB join

insert overwrite table jointable
select b.id, b.t, b.uid, b.keyword, b.url_rank, b.click_num, b.click_url
from bigtable_buck1 s
join bigtable_buck2 b
on b.id = s.id;

10.2.7 笛卡尔积

1、产生笛卡尔积的条件：
1）两个表join时不写on条件
2）两个表join时on条件无效
2、问题：Hive中笛卡尔积的查询只能使用一个Reducer来完成，面对海量数据很容易出现问题。
Map阶段：在这个阶段，系统对输入数据进行初步处理，通常是分解和转换操作。例如，它可能对数据集进行排序或筛选。
Reduce阶段：在Map阶段之后进行的是Reduce阶段。在这个阶段，Reduce接收来自Mapper的输出数据，并对这些数据进行汇总、整合或其它形式的处理，并生成最终的输出结果。
3、解决：不要写笛卡尔积，开启严格模式，不允许在HQL中出现笛卡尔积

10.3 数据倾斜

1、数据倾斜现象：
绝大多数任务都很快完成，只有一个或者少数几个任务执行的很慢甚至最终执行失败。
2、数据过量现象：
数据过量的表现为所有任务都执行的很慢，这个时候只有提高执行资源才可以优化HQL的执行效率。
3、数据倾斜的原因：
导致倾斜的原因在于按照key分组后，少量的任务负载着绝大部分数据的计算，也就是说，产生数据倾斜的HQL中一定存在分组的操作。所有从HQL的角度，我们可用将数据倾斜分为单表携带了Group by字段的查询和两表（多表）join的查询。

10.3.1 单表数据倾斜优化

1、使用参数优化
当任务中存在group by操作同时聚合函数为count或者sum可用设置参数来处理数据倾斜的问题，就是上文的Group by处理方式。
1）是否在Map端进行聚合，默认为True

set hive.map.aggr = true

2）在Map端进行聚合操作的条目数目

set hive.groupby.mapaggr.checkinterval = 100000

3）有数据倾斜的时候进行负载均衡（默认是false）

set hive.groupby.skewindata = true

2、增加Reduce数量
当数据中的多个key同时导致数据倾斜，可用通过增加reduce的数量解决数据倾斜问题
1）调整Reduce个数方法1：
（1）每个Reduce处理的数据量默认是256MB

set hive.exec.reducers.bytes.per.reducer=256000000

（2）每个任务最大的reduce数，默认为1009

set hive.exec.reducers.max=1009

（3）计算reducer数的公式

N=min(参数2，总输入数据量/参数1)

2）调整Reduce个数方法2：
通过参数配置的方式（三种）直接指定reduce的个数，参数mapreduce.job.reduces。

set mapreduce.job.reduces = 15;

10.3.1 join数据倾斜优化

1、使用参数
在编写Join查询语句时，如果确定是由于join出现的数据倾斜，那么请坐如下设置。

# join的键对应的记录条数超过这个值则会进行分拆，值根据具体数据量设置
set hive.skewjoin.key=100000;
# 如果是join过程出现倾斜应该设置为true
set hive.optimize.skewjoin=false;

如果开启了，在Join过程中Hive会将计数超过阈值hive.skewjoin.key（默认100000）的倾斜key对应的行临时写入文件中，然后再启动另一个job左map join生成结果。通过hive.skewjoin.mapjoin.map.tasts参数还可以控制第二个job的mapper数量，默认10000。

set hive.skewjoin.mapjoin.map.tasks=10000;

2、大小表join
可用使用MapJoin，没有Reduce阶段就不会出现数据倾斜。
3、大表大表join
使用大散加扩容方式解决数据倾斜问题
选择其中较大的表做打散处理：

select *,concat(id,'-','0 or 1 or 2') from A;t1

选择其中较小的表做扩容处理

select *,concat(id,'-','0') from B
union all
select *,concat(id,'-','1') from B
union all
select *,concat(id,'-','2') from B;t2

10.4 Hive job优化

10.4.1 Hive Map阶段优化

1、负载文件增加Map数量
1）使用场景：当input的文件都很大，任务逻辑复杂，map执行非常慢的时候，可用考虑增加Map数，来使得每个map处理的数据量减少，从而提高任务的执行效率。
2）增加map数据的方法：

computeSliteSize(Math.max(minSize,Math.min(maxSize,blocksize)))=blocksize=128M

公式调整maxSize最大值。让maxSize最大值低于blocksize就可以增加map的个数。
3）案例：
（1）执行查询

select count(*) from emp;
Hadoop job information for Stage-1: number of mappers: 1; number of reducers: 1

（2）设置最大切片值为100个字节

set mapreduce.input.fileinputformat.split.maxsize=100;
select count(*) from emp;
Hadoop job information for Stage-1: number of mappers: 6; number of reducers: 1

2、小文件进行合并
1）再map执行前合并小文件，减少map数：
CombineHiveInputFormat具有对小文件进行合并的功能（系统默认的格式）。
HiveInputFormat没有对小文件合并功能。

set hive.input.format= org.apache.hadoop.hive.ql.io.CombineHiveInputFormat;

2）再Map-Reduce的任务结束时合并小文件的设置
在map-only任务结束时合并小文件，默认true

SET hive.merge.mapfiles = true;

在map-reduce任务结束时合并小文件，默认false

SET hive.merge.mapredfiles = true;

合并文件的大小，默认256M

SET hive.merge.size.per.task = 268435456;

当输出文件的平均大小小于该值时，启动一个独立的map-reduce任务进行文件merge

SET hive.merge.smallfiles.avgsize = 16777216;

3、Map端聚合

set hive.map.aggr=true;//相当于map端执行combiner

10.4.2 Hive Reduce优化

1、合理设置Reduce数
1）调整reduce个数方法一
（1）每个Reduce处理的数据量默认是256MB

set hive.exec.reducers.bytes.per.reducer=256000000

（2）每个任务最大的reduce数，默认为1009

set hive.exec.reducers.max=1009

（3）计算reducer数的公式

N=min(参数2，总输入数据量/参数1)

2）调整reduce个数方法二
通过参数配置的方式（三种）直接指定reduce的个二叔，参数mapreduce.job.reduces。

set mapreduce.job.reduces = 15;

3）reduce个数不是越多越好
（1）过多的启动和初始化reduce也会消耗时间和资源
（2）另外，有多少个reduce，就会有多少个输出文件，如果生成了很多个小文件，那么如果这些小文件作为下一个文件的输入，则会出现小文件过多的问题。
（3）在设置reduce个数的时候也需要考虑这两个问题：处理大数据量利用合适的redece数；使单个reduce任务处理数据量大小要合适。

10.4.3 Hive任务整体优化

1、Fetch抓取
Fetch抓取是指，Hive中对某些情况的查询可以不必使用MapReduce计算。例如：select * from emp;在这种情况下，Hive可以简单地读取emp对应地存储目录下的文件，然后输出查询结果到控制台。在hive-default.xml.template文件中hive.fetch.task.conversion默认是more，老版本hive默认minimal，该属性修改为more以后，在全局查询、字段查询、limit查询等都不走mapreduce。

<property>
    <name>hive.fetch.task.conversion</name>
    <value>more</value>
    <description>
      Expects one of [none, minimal, more].
      Some select queries can be converted to single FETCH task minimizing latency.
      Currently the query should be single sourced not having any subquery and should not have any aggregations or distincts (which incurs RS), lateral views and joins.
      0. none : disable hive.fetch.task.conversion
      1. minimal : SELECT STAR, FILTER on partition columns, LIMIT only
      2. more  : SELECT, FILTER, LIMIT only (support TABLESAMPLE and virtual columns)
    </description>
</property>

1）案例：
（1）把hive.fetch.task.conversion设置成none，然后执行查询语句，都会执行mapreduce程序。

set hive.fetch.task.conversion=none;
select * from emp;
select ename from emp;
select ename from emp limit 3;

（2）把hive.fetch.task.conversion设置成more，然后执行查询语句，如下查询语句都不会执行mapreduce程序。

set hive.fetch.task.conversion=more;
select * from emp;
select ename from emp;
select ename from emp limit 3;

2、本地模式
1）本地模式介绍
（1）大多数的Hadoop Job是需要Hadoop提供的完整的可扩展性来处理大数据集的。
（2）不过，有时Hive的输入数据量是非常小的。在这种情况下，为查询触发执行任务消耗的时间可能会比实际job的执行时间要多的多。
（3）对于大多数这种情况，Hive可以通过本地模式在单台机器上处理所有的任务。对于小数据集，执行时间可以明显被缩短。
（4）用户可以通过设置hive.exec.mode.local.auto=true，来让Hive在适当的时候自动启动这个优化。

set hive.exec.mode.local.auto=true;   //开启本地mr
// 设置local mr的最大输入数据量，当输入数据量小于这个值时采用local mr的方式，默认为134217728，即128M
set hive.exec.mode.local.auto.inputbytes.max=50000000;
// 设置local mr的最大输入文件个数，当输入文件个数小于这个值时采用local mr的方式，默认为4
set hive.exec.mode.local.auto.input.files.max=10;

2）案例：
（1）开启本地模式，并执行查询语句

set hive.exec.mode.local.auto=true;
select * from emp cluster by deptno;
……
Ended Job = job_local177532144_0001
……
Time taken: 1.328 seconds, Fetched: 14 row(s)

（2）关闭本地模式，并执行查询语句

set hive.exec.mode.local.auto=false;
select * from emp cluster by deptno;
……
Starting Job = job_1634825444943_0018, Tracking URL = http://hadoop103:8088/proxy/application_1634825444943_0018/
……
Time taken: 20.09 seconds, Fetched: 14 row(s)

3、并行执行
Hive会将一个查询转化成一个或者多个阶段。这样的阶段可以是MapReduce阶段、抽样阶段、合并阶段、limit阶段。或者Hive执行过程中可能需要的其它阶段。默认情况下，Hive依次只会执行一个阶段。不过，某个特定的job可能包含众多的阶段，而这些阶段可能并非完全互相依赖的，也就是说有些阶段是可以并行执行的，这样可能使得整个job的执行时间缩短。不过，如果有更多的阶段可以并行执行，那么job可能就越快完成。通过设置参数hive.exec.parallel=true，就可以开启并发执行。不过，在共享集群中，需要注意下，如果job中并行阶段增多，那么集群利用率就会增加。

set hive.exec.parallel=true;            //打开任务并行执行
set hive.exec.parallel.thread.number=16;  //同一个sql允许最大并行度，默认为8。

当然，的在系统资源比较空闲的时候才有优势，否则，没资源，并行不起来。
4、严格模式
1）介绍：Hive可以通过设置防止一些危险操作
2）分区表不适用分区过滤
将hive.strict.checks.no.partition.filter=true时，对于分区表，除非where语句中含有分区字段过滤条件来限制范围，否则不允许执行。换句话说，就是用户不允许扫描所有分区。进行这个限制的原因是，通常分区表都拥有非常大的数据集，而且数据增加迅速。没有进行分区限制的查询可能会消耗令人不可接受的巨大资源来处理这个表。

set hive.strict.checks.no.partition.filter=true;
select * from dept_partition;
FAILED: SemanticException [Error 10056]: Queries against partitioned tables without a partition filter are disabled for safety reasons. If you know what you are doing, please set hive.strict.checks.no.partition.filter to false and make sure that hive.mapred.mode is not set to 'strict' to proceed. Note that you may get errors or incorrect results if you make a mistake while using some of the unsafe features. No partition predicate for Alias "dept_partition" Table "dept_partition"

3）使用order by 没有limit过滤
将hive.strict.checks.orderby.no.limit=true时，对于使用了order by语句的查询，要求必须使用limit语句。应为order by为了执行排序过程中会将所有的结果数据分发到同一个Reducer中进行处理，强制要求用户增加这个LIMIT语句可以防止Reducer额外执行很长一段时间。

set hive.strict.checks.orderby.no.limit=true;
select * from emp order by sal;
FAILED: SemanticException 1:27 Order by-s without limit are disabled for safety reasons. If you know what you are doing, please set hive.strict.checks.orderby.no.limit to false and make sure that hive.mapred.mode is not set to 'strict' to proceed. Note that you may get errors or incorrect results if you make a mistake while using some of the unsafe features.. Error encountered near token 'sal'

4）笛卡尔积
将hive.strict.checks.cartesian.product=true时，会限制笛卡尔积的查询。对关系型数据块非常了解的用户可能期望在执行JOIN查询的时候不使用ON语句而是使用where语句，这样关系数据库的执行优化器就可以高效地将WHERE语句转化成那个ON语句。不幸的是,Hive并不会执行这种优化，因此，如果表足够大，那么这个查询就会出现不可控的情况。文章来源地址https://www.toymoban.com/news/detail-801545.html

set hive.strict.checks.orderby.no.limit=true;
select * from emp order by sal;
FAILED: SemanticException 1:27 Order by-s without limit are disabled for safety reasons. If you know what you are doing, please set hive.strict.checks.orderby.no.limit to false and make sure that hive.mapred.mode is not set to 'strict' to proceed. Note that you may get errors or incorrect results if you make a mistake while using some of the unsafe features.. Error encountered near token 'sal'