Unity中URP下实现深度贴花-Toy模板网

这篇具有很好参考价值的文章主要介绍了Unity中URP下实现深度贴花。希望对大家有所帮助。如果存在错误或未考虑完全的地方，请大家不吝赐教，您也可以点击"举报违法"按钮提交疑问。

前言

在游戏中，有很多用到贴画的地方。比如：地面污渍、地面喷漆、地面血迹、魔法阵、地裂等效果。
我们在这篇文章中，来用深度图实现一下贴画的效果。

一、场景设置

使用之前的棋盘格设置一个场景，且在场景中，增加一些物体，来给贴花吸附。
然后，我们创建一个面片用于承载贴花Shader
我们要实现的贴花效果是会吸附在物体上的。
但是，我们目前的面片没有这个功能，我们接下来就需要来实现贴花的吸附功能。

二、实现思路

1、通过深度图求出像素所在视图空间的Z值

2、通过模型面片的求出像素在观察空间下的坐标值

3、结合两者求出深度图中像素的 XYZ值

4、再将此坐标转换到模型的本地空间，把XY作为UV来进行纹理采样

三、URP下实现

1、通过深度图求出像素所在视图空间的Z值

在URP设置中，开启深度图
申明纹理和采样器

TEXTURE2D(_CameraDepthTexture);SAMPLER(sampler_CameraDepthTexture);

在片元着色器，得到观察空间下的深度图Z值

float4 depthVS = 1;
float2 screenUV = i.positionCS.xy / _ScreenParams.xy;
half depthTex = SAMPLE_TEXTURE2D(_CameraDepthTexture,sampler_CameraDepthTexture,screenUV);
half depthZ = LinearEyeDepth(depthTex,_ZBufferParams);
depthVS.z = depthZ;

2、通过模型面片的求出像素在观察空间下的坐标值

这步需要在顶点着色器中完成
在片元着色器输入结构体中,增加一条用于存储模型观察空间坐标值

float3 positionVS : TEXCOORD3;

在片元着色器中，将模型顶点本地空间转化为观察空间

o.positionVS = TransformWorldToView(TransformObjectToWorld(o.positionOS));

3、结合两者求出深度图中像素的 XYZ值

我们来推导一下公式
点 $P$ 是模型上的点在观察空间下的值
$W_z$ 是深度图在观察空间下的Z值

我们先在 $X o Z$ 平面下求出我们的 $W_x$ 值
$\frac{P_z}{W_z}=\frac{P_x}{W_x}$
$W_x = \frac{P_xW_z}{P_z}$
$P_z$ 为负数， $W_z$ 为正数
我们需要的比值只是一个长度关系。所以，需要乘以一个 $- 1$
$W_x = \frac{P_xW_z}{-P_z}$
然后，在 $Y o Z$ 平面下求出我们的 $W_y$ 值
$W_y = \frac{P_yW_z}{-P_z}$

depthVS.xy = i.positionVS.xy*depthZ/-i.positionVS.z;

4、再将此坐标转换到模型的本地空间，把XY作为UV来进行纹理采样

float4 depthWS = mul(unity_CameraToWorld,depthVS);
float4 depthOS = mul(unity_WorldToObject,depthWS);
float2 uv = depthOS.xy+0.5;
half4 mainTex = SAMPLE_TEXTURE2D(_MainTex,sampler_MainTex,uv);

四、最终效果

Unity中URP下实现深度贴花,Unity,unity,游戏引擎文章来源地址https://www.toymoban.com/news/detail-811976.html

//深度贴花
Shader "MyShader/URP/P4_4_2"
{
    Properties
    {
        [Header(MainTex)]
        _MainTex("MainTex",2D) = "white"{}

    }
    SubShader
    {
        Tags
        {
            //告诉引擎，该Shader只用于 URP 渲染管线
            "RenderPipeline"="UniversalPipeline"
            //渲染类型
            "RenderType"="Transparent"
            //渲染队列
            "Queue"="Transparent"
        }

        Pass
        {
            Blend One One
            ZWrite Off
            Name "Unlit"

            HLSLPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fog
            // Pragmas
            #pragma target 2.0

            // Includes
            #include "Packages/com.unity.render-pipelines.core/ShaderLibrary/Color.hlsl"
            #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"
            #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Input.hlsl"

            CBUFFER_START(UnityPerMaterial)
                float4 _MainTex_ST;
            CBUFFER_END

            TEXTURE2D(_MainTex);
            SAMPLER(sampler_MainTex);
            TEXTURE2D(_CameraDepthTexture);
            SAMPLER(sampler_CameraDepthTexture);
            //struct appdata
            //顶点着色器的输入
            struct Attributes
            {
                float3 positionOS : POSITION;
                float2 uv : TEXCOORD0;
            };

            //struct v2f
            //片元着色器的输入
            struct Varyings
            {
                float4 positionCS : SV_POSITION;
                float2 uv : TEXCOORD0;
                float fogCoord : TEXCOORD1;
                float3 positionOS : TEXCOORD2;
                float3 positionVS : TEXCOORD3;
            };

            //v2f vert(Attributes v)
            //顶点着色器
            Varyings vert(Attributes v)
            {
                Varyings o = (Varyings)0;
                o.positionCS = TransformObjectToHClip(v.positionOS);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                o.fogCoord = ComputeFogFactor(o.positionCS.z);
                o.positionOS = v.positionOS;
                //2、通过模型面片的求出像素在观察空间下的坐标值
                o.positionVS = TransformWorldToView(TransformObjectToWorld(o.positionOS));
                return o;
            }

            //fixed4 frag(v2f i) : SV_TARGET
            //片元着色器
            half4 frag(Varyings i) : SV_TARGET
            {
                //思路：
                float4 depthVS = 1;
                //1、通过深度图求出像素所在视图空间的Z值
                float2 screenUV = i.positionCS.xy / _ScreenParams.xy;
                half4 depthTex = SAMPLE_TEXTURE2D(_CameraDepthTexture, sampler_CameraDepthTexture, screenUV);
                half depthZ = LinearEyeDepth(depthTex.r, _ZBufferParams);

                //2、通过模型面片的求出像素在观察空间下的坐标值
                //这个在顶点着色器中完成

                //3、结合两者求出 深度图中像素的 XYZ值
                depthVS.z = depthZ;
                depthVS.xy = i.positionVS.xy * depthZ / -i.positionVS.z;
                //4、再将此坐标转换到模型的本地空间，把XY作为UV来进行纹理采样
                float4 depthWS = mul(unity_CameraToWorld, depthVS);
                float4 depthOS = mul(unity_WorldToObject, depthWS);
                float2 uv = depthOS.xy + 0.5;

                half4 col = 0;
                half4 mainTex = SAMPLE_TEXTURE2D(_MainTex, sampler_MainTex, uv);
                col += mainTex;

                return col;
            }
            ENDHLSL
        }
    }
}

到了这里，关于Unity中URP下实现深度贴花的文章就介绍完了。如果您还想了解更多内容，请在右上角搜索TOY模板网以前的文章或继续浏览下面的相关文章，希望大家以后多多支持TOY模板网！